Random number generator

While truly random numbers are difficult to create with a deterministic computer, a pseudorandom number generator, or PRNG, may be used instead, which is technically deterministic, but designed so that the output should appear consistently uncorrelated. There are a wide variety of suitable algorithms.

Typically a starting "seed" is supplied by the program to begin the sequence generated by a PRNG. By finding some way of gathering a suitably unpredictable starting seed, (e.g. counting the time until the user presses a button) the program can start at a different part of the sequence each time it is run, ensuring the user does not have the same experience twice.

Linear feedback shift register

The linear feedback shift register is commonly used as a PRNG on systems like the 6502 which have no hardware multiply capabilities. This rotates a series of bits (the shift register), with the bit coming off the end of the series feeding back into the register as an exclusive-OR operation. By choosing the feedback bits carefully, this can create a sequence that fills the register with every possible value (except 0), allowing relatively long random number sequences using only bitwise operations.

This example is only 16 bits wide, but the sequence length of an LSFR can be doubled with each bit. 24 and 32 bit LSFRs are very practical if extremely long sequences are needed.

; prng
;
; Returns a random 8-bit number in A (0-255), clobbers X (0).
;
; Requires a 2-byte value on the zero page called "seed".
; Initialize seed to any value except 0 before the first call to prng.
; (A seed value of 0 will cause prng to always return 0.)
;
; This is a 16-bit Galois linear feedback shift register with polynomial $002D.
; The sequence of numbers it generates will repeat after 65535 calls.
;
; The value loaded in X controls the quality of randomness.  Each iteration
; produces another bit worth of entropy.  All 8 bits will produce maximum
; entropy, but this value can be lowered to increase speed if you are using
; only low-order bits.  If using the same value each time (prng), use
; 8, 7, 4, 2, 1.  Avoid long runs of 6, 5 and 3, as they shorten the
; sequence by having common factors with 65535.  If you use different amounts
; of low-order bits each time, such as to produce random numbers in different
; ranges in different parts of a game, you can use prng_xbits.
; 
;
; Execution time is an average of 125 cycles (excluding jsr and rts)

.zeropage
seed: .res 2       ; initialize 16-bit seed to any value except 0

.code
prng:
	ldx #8     ; iteration count: controls entropy quality (max 8,7,4,2,1 min)
prng_xbits:
	lda seed+0
@bitloop:
	asl        ; shift the register
	rol seed+1
	bcc :+
	eor #$2D   ; apply XOR feedback whenever a 1 bit is shifted out
:
	dex
	bne @bitloop
	sta seed+0
	cmp #0     ; reload flags
	rts

References

• Codebase64.org PRNG code examples

Past forum discussions of random number generators:

• Forum: Quality of the CC65 randomizer
• Forum: Which randomizer to use?
• Forum: need assistance with random number generator
• Forum: CRC routines as PRNGs